systems ∿ encounter video study


06 February 2018

13 minutes of wild sounds…

// sound definitions used in the study

t.quelle('a', {|in, c|
    SinOscFB.ar(1400 * Amplitude.ar(in, 0.01, 1), (in * 2).clip(0, 2).lagud(0, 0.2))
});
t.quelle('e', {|in, c|
    LotkaVolterra.ar(SampleRate.ir*0.5,
        a: SinOsc.ar(in.lag(0.1), 0, 10).abs.clip(0, 5),
        b: 1.5,
        c: 0.5,
        d: 1.5,
        h: 0.01,
        xi: 0.1
    ).flop.flat.keep(2) * 0.1
});
t.quelle('i', {|in, c|
    Impulse.ar([3, 8])
});
t.quelle('o', {|in, c|
    SinOscFB.ar(ExpRand(100, 200), in) - in.lag(0.01)
});
t.quelle('u', {|in, c|
    SinOscFB.ar(ExpRand(100, 200), 0.1)!2
});
t.filter('f', {|in, c|
    var dyn = RMS.ar(in, 100).lag(0.1) * 2;

    RLPF.ar(in * 0.1, 1800 - (dyn.reverse * 400), dyn * 0.5)
});
t.filter('l', {|in, c|
    in * LFTri.ar(RMS.ar(in).lag(0.1) * 10)
});
t.filter('d', {|in, c|
    DelayL.ar(in, 0.2, RMS.ar(in).lag(0.1).reverse.clip(0, 0.2))
});
t.filter('n', {|in, c|
    in.scramble.clump(2).collect{|in|
        MyRotate2.ar(in, LFNoise1.kr(0.1))
    }.flat
});
t.filter('g', {|in, c|
    HairCell.ar(in,
        spontaneousrate: 0,
        boostrate: 200,
        restorerate: 1000,
        loss: 0.99,
        mul: 1,
        add: 0
    )
});
t.filter('x', {|in, c|
    CombL.ar(in, 0.2, 0.2)
});

Get Steno.